This is a canonical fold homoclinic bursting neuron model.  It is a quadritic integrate and fire spiking mechanism driven through a hysteresis loop by a linear slow variable.

μ=0.04;(*period 1*)
μ=0.038;(*period 2*)
μ=0.03697;(*period 4*)
μ=0.0369;(*period 8*)
μ=0.03688;(*period 16*)
μ=0.0365;(*chaos*)
μ=0.0363;(*miniburst, not chaos*)
μ=0.0362;(*chaos*)
μ=0.0361;(*edge of chaos stable bursting*);
μ=0.02;(*bursting*)

(*parameters*)
μ=0.0362;(*chaos*)
i=1;
d=0.2;
vreset=1;
vcrit=10;

(*state equations*)
dvdt=v'[t]==i+v[t]^2-u[t];(*AP producing mechanism*)
dudt=u'[t]==-μ*u[t];(*slow subsystem*)

t0 = 0;
{v0,u0}={-1,1};(*initial conditions*)
system = {dvdt,dudt,v[t0]==v0,u[t0]==u0};(*compact system*)
event=v[t]-vcrit;(*event*)
odemethod = Automatic;(*RK4*)
numspikes=200;
numtrials=4;

(*hybrid system solver*)
DataArray={};
uSection={};(*poincare section at u-peaks*)
Do[
data ={};
NDSolve[
{dvdt,dudt,v[t0]==v0,u[t0]==u0},{v,u},{t,t0,Infinity},Method->{"EventLocator","Event"->event,Direction->1,EventAction:>Throw[{t0=t;v0=vreset;u0=u[t]+d;AppendTo[uSection,u[t]]},"StopIntegration"],Method->odemethod},MaxStepFraction->1,StepMonitor:>AppendTo[data,{t,v[t],u[t]}]];(*record info for uMap*)
AppendTo[DataArray,data],
{numspikes}];

(*data interpolation*)
trajdata =Flatten[ Join[DataArray],1];
sol={Interpolation[{#[[1]],#[[2]]}&/@trajdata,InterpolationOrder->0][t],Interpolation[{#[[1]],#[[3]]}&/@trajdata,InterpolationOrder->0][t]};
timetotal=Interpolation[{#[[1]],#[[2]]}&/@trajdata][[1,1,2]];

(*Plot*)
p1=ParametricPlot[{sol[[2]],sol[[1]]},{t,200,400},PlotRange->All,AspectRatio->1,Frame->True,FrameLabel->{u,v}];
p2=Plot[sol[[1]],{t,200,400},PlotRange->All,AspectRatio->1,AxesLabel->{t,v}];
GraphicsGrid[{{p1,p2}}]

(*The following is a one-dimensional map that is created by looking at the value of the slow variable u before each spike reset*)
uMapList=Table[{uSection[[i]],uSection[[i+1]]},{i,1,Length[uSection]-1}];
uMap=Interpolation[Select[uMapList,#[[2]]>1.6&],InterpolationOrder->5];
rangemap=Flatten[uMap[[1]]];

(*Cobweb the map*)
MapSegments[x0_,its_]:=Module[
{l=NestList[uMap[#]&,x0,its]},
Partition[Flatten[Transpose[{l,l}]],2,1]
]
p2=Partition[MapSegments[1.7439086294678086`,5],2,1];(*enter intial u value and number of iterations*)

(*plot the results*)
cobweb=Table[Graphics[{Darker[Darker[Blue]],Line[p2[[i]]]}],{i,1,Length[p2]}];
returnLine=Plot[x,{x,0,1.9},PlotStyle->{Black,Dashed}];
map=Plot[uMap[x],{x,rangemap[[1]],rangemap[[2]]},PlotStyle->{Thick,Black}];
Show[map,returnLine,cobweb,Axes->False,Frame->True,FrameStyle->Large,FrameLabel->{"(Subscript[u, n])","(Subscript[u, n + 1])"},AspectRatio->1,PlotRange->{{1.65,1.84},{1.65,1.84}}]